mirror of
https://github.com/eworm-de/routeros-scripts
synced 2024-05-14 08:04:19 +00:00
870f00bb36
___ _ ___ __
/ _ )(_)__ _ / _/__ _/ /_
/ _ / / _ `/ / _/ _ `/ __/
/____/_/\_, / /_/ \_,_/\__/
_ __ /___/ _ __
| | / /___ __________ (_)___ ____ _/ /
| | /| / / __ `/ ___/ __ \/ / __ \/ __ `/ /
| |/ |/ / /_/ / / / / / / / / / / /_/ /_/
|__/|__/\__,_/_/ /_/ /_/_/_/ /_/\__, (_)
/____/
RouterOS has some odd behavior when it comes to variable names. Let's
have a look at the interfaces:
[admin@MikroTik] > / interface print where name=en1
Flags: D - dynamic, X - disabled, R - running, S - slave
# NAME TYPE ACTUAL-MTU L2MTU
0 RS en1 ether 1500 1598
That looks ok. Now we use a script:
{ :local interface "en1";
/ interface print where name=$interface; }
And the result...
[admin@MikroTik] > { :local interface "en1";
{... / interface print where name=$interface; }
Flags: D - dynamic, X - disabled, R - running, S - slave
# NAME TYPE ACTUAL-MTU L2MTU
0 RS en1 ether 1500 1598
... still looks ok.
We make a little modification to the script:
{ :local name "en1";
/ interface print where name=$name; }
And the result:
[admin@MikroTik] > { :local name "en1";
{... / interface print where name=$name; }
Flags: D - dynamic, X - disabled, R - running, S - slave
# NAME TYPE ACTUAL-MTU L2MTU
0 RS en1 ether 1500 1598
1 S en2 ether 1500 1598
2 S en3 ether 1500 1598
3 S en4 ether 1500 1598
4 S en5 ether 1500 1598
5 R br-local bridge 1500 1598
Ups! The filter has no effect!
That happens whenever the variable name ($name) matches the property
name (name=).
And another modification:
{ :local type "en1";
/ interface print where name=$type; }
And the result:
[admin@MikroTik] > { :local type "en1";
{... / interface print where name=$type; }
Flags: D - dynamic, X - disabled, R - running, S - slave
# NAME TYPE ACTUAL-MTU L2MTU
Ups! Nothing?
Even if the variable name ($type) matches whatever property name (type=)
things go wrong.
The answer from MikroTik support (in Ticket#2019010222000454):
> This is how scripting works in RouterOS and we will not fix it.
To get around this we use variable names in CamelCase. Let's hope
Mikrotik never ever introduces property names in CamelCase...
*fingers crossed*
63 lines
2.4 KiB
Plaintext
63 lines
2.4 KiB
Plaintext
#!rsc
|
|
# RouterOS script: check-routeros-update
|
|
# Copyright (c) 2013-2019 Christian Hesse <mail@eworm.de>
|
|
#
|
|
# check for RouterOS update, send notification e-mails
|
|
|
|
:global Identity;
|
|
:global SafeUpdateUrl;
|
|
:global SentRouterosUpdateNotification;
|
|
|
|
:global SendNotification;
|
|
|
|
:if ([ / system package print count-only where name="wireless" disabled=no ] > 0) do={
|
|
:if ([ / interface wireless cap get enabled ] = true && \
|
|
[ / caps-man manager get enabled ] = false) do={
|
|
:error "System is managed by CAPsMAN, not checking.";
|
|
}
|
|
}
|
|
|
|
/ system package update check-for-updates without-paging;
|
|
:local InstalledVersion [ / system package update get installed-version ];
|
|
:local LatestVersion [ / system package update get latest-version ];
|
|
|
|
:if ($InstalledVersion != $LatestVersion) do={
|
|
:local Channel [ / system package update get channel ];
|
|
:local Model [ / system routerboard get model ];
|
|
:local SerialNumber [ / system routerboard get serial-number ];
|
|
|
|
:if ([ :len $SafeUpdateUrl ] > 0) do={
|
|
:local Result;
|
|
:do {
|
|
:set Result [ / tool fetch check-certificate=yes-without-crl \
|
|
($SafeUpdateUrl . $Channel . "?installed=" . $InstalledVersion . \
|
|
"&latest=" . $LatestVersion) output=user as-value ];
|
|
} on-error={
|
|
:log warning ("Failed receiving safe version for " . $Channel . ".");
|
|
}
|
|
:if ($Result->"status" = "finished" && $Result->"data" = $LatestVersion) do={
|
|
:log info ("Version " . $LatestVersion . " is considered safe, updating...");
|
|
$SendNotification ("RouterOS update notification") \
|
|
("Version " . $LatestVersion . " is considered safe for " . $Channel . \
|
|
", updating on " . $Identity . "...");
|
|
/ system package update install;
|
|
:error "Waiting for system to reboot.";
|
|
}
|
|
}
|
|
|
|
:if ($SentRouterosUpdateNotification = $LatestVersion) do={
|
|
:error ("Already sent the RouterOS update notification for version " . \
|
|
$LatestVersion . ".");
|
|
}
|
|
|
|
$SendNotification ("RouterOS update notification") \
|
|
("There is a RouterOS update available\n\n" . \
|
|
"Routerboard: " . $Model . "\n" . \
|
|
"Serial number: " . $SerialNumber . "\n" . \
|
|
"Hostname: " . $Identity . "\n" . \
|
|
"Channel: " . $Channel . "\n" . \
|
|
"Installed: " . $InstalledVersion . "\n" . \
|
|
"Available: " . $LatestVersion);
|
|
:set SentRouterosUpdateNotification $LatestVersion;
|
|
}
|