mirror of
https://github.com/eworm-de/routeros-scripts
synced 2024-05-14 08:04:19 +00:00
870f00bb36
___ _ ___ __
/ _ )(_)__ _ / _/__ _/ /_
/ _ / / _ `/ / _/ _ `/ __/
/____/_/\_, / /_/ \_,_/\__/
_ __ /___/ _ __
| | / /___ __________ (_)___ ____ _/ /
| | /| / / __ `/ ___/ __ \/ / __ \/ __ `/ /
| |/ |/ / /_/ / / / / / / / / / / /_/ /_/
|__/|__/\__,_/_/ /_/ /_/_/_/ /_/\__, (_)
/____/
RouterOS has some odd behavior when it comes to variable names. Let's
have a look at the interfaces:
[admin@MikroTik] > / interface print where name=en1
Flags: D - dynamic, X - disabled, R - running, S - slave
# NAME TYPE ACTUAL-MTU L2MTU
0 RS en1 ether 1500 1598
That looks ok. Now we use a script:
{ :local interface "en1";
/ interface print where name=$interface; }
And the result...
[admin@MikroTik] > { :local interface "en1";
{... / interface print where name=$interface; }
Flags: D - dynamic, X - disabled, R - running, S - slave
# NAME TYPE ACTUAL-MTU L2MTU
0 RS en1 ether 1500 1598
... still looks ok.
We make a little modification to the script:
{ :local name "en1";
/ interface print where name=$name; }
And the result:
[admin@MikroTik] > { :local name "en1";
{... / interface print where name=$name; }
Flags: D - dynamic, X - disabled, R - running, S - slave
# NAME TYPE ACTUAL-MTU L2MTU
0 RS en1 ether 1500 1598
1 S en2 ether 1500 1598
2 S en3 ether 1500 1598
3 S en4 ether 1500 1598
4 S en5 ether 1500 1598
5 R br-local bridge 1500 1598
Ups! The filter has no effect!
That happens whenever the variable name ($name) matches the property
name (name=).
And another modification:
{ :local type "en1";
/ interface print where name=$type; }
And the result:
[admin@MikroTik] > { :local type "en1";
{... / interface print where name=$type; }
Flags: D - dynamic, X - disabled, R - running, S - slave
# NAME TYPE ACTUAL-MTU L2MTU
Ups! Nothing?
Even if the variable name ($type) matches whatever property name (type=)
things go wrong.
The answer from MikroTik support (in Ticket#2019010222000454):
> This is how scripting works in RouterOS and we will not fix it.
To get around this we use variable names in CamelCase. Let's hope
Mikrotik never ever introduces property names in CamelCase...
*fingers crossed*
34 lines
1.3 KiB
Text
34 lines
1.3 KiB
Text
#!rsc
|
|
# RouterOS script: check-lte-firmware-upgrade
|
|
# Copyright (c) 2018-2019 Christian Hesse <mail@eworm.de>
|
|
#
|
|
# check for LTE firmware upgrade, send notification e-mails
|
|
|
|
:global Identity;
|
|
:global SentLteFirmwareUpgradeNotification;
|
|
|
|
:global SendNotification;
|
|
|
|
:foreach Interface in=[ / interface lte find ] do={
|
|
:local IntName [ / interface lte get $Interface name ];
|
|
:do {
|
|
:local Firmware [ / interface lte firmware-upgrade $Interface once as-value ];
|
|
# strip the extra line break (TODO: remove when fixed upstream)
|
|
:set ($Firmware->"latest") [ :pick ($Firmware->"latest") 0 [ :find ($Firmware->"latest") "\n" ] ];
|
|
|
|
:if ($SentLteFirmwareUpgradeNotification = ($Firmware->"latest")) do={
|
|
:log debug ("Already sent the LTE firmware upgrade notification for version " . \
|
|
($Firmware->"latest") . ".");
|
|
} else={
|
|
:if (($Firmware->"installed") != ($Firmware->"latest")) do={
|
|
$SendNotification ("LTE firmware upgrade notification") \
|
|
("A new firmware version " . ($Firmware->"latest") . " is available for " . \
|
|
"LTE interface " . $IntName . " on " . $Identity . ".");
|
|
:set SentLteFirmwareUpgradeNotification ($Firmware->"latest");
|
|
}
|
|
}
|
|
} on-error={
|
|
:log debug ("Could not get latest LTE firmware version for interface " . \
|
|
$IntName . ".");
|
|
}
|
|
}
|