mirror of
https://github.com/eworm-de/routeros-scripts
synced 2024-05-14 08:04:19 +00:00
77 lines
3.5 KiB
Text
77 lines
3.5 KiB
Text
#!rsc by RouterOS
|
|
# RouterOS script: collect-wireless-mac%TEMPL%
|
|
# Copyright (c) 2013-2021 Christian Hesse <mail@eworm.de>
|
|
# https://git.eworm.de/cgit/routeros-scripts/about/COPYING.md
|
|
#
|
|
# collect wireless mac adresses in access list
|
|
# https://git.eworm.de/cgit/routeros-scripts/about/doc/collect-wireless-mac.md
|
|
#
|
|
# !! This is just a template! Replace '%PATH%' with 'caps-man'
|
|
# !! or 'interface wireless'!
|
|
|
|
:local 0 "collect-wireless-mac%TEMPL%";
|
|
:global GlobalFunctionsReady;
|
|
:while ($GlobalFunctionsReady != true) do={ :delay 500ms; }
|
|
|
|
:global Identity;
|
|
|
|
:global GetMacVendor;
|
|
:global LogPrintExit2;
|
|
:global ScriptLock;
|
|
:global SendNotification2;
|
|
:global SymbolForNotification;
|
|
|
|
$ScriptLock $0;
|
|
|
|
:if ([ :len [ / %PATH% access-list find where comment="--- collected above ---" disabled ] ] = 0) do={
|
|
/ %PATH% access-list add comment="--- collected above ---" disabled=yes;
|
|
$LogPrintExit2 warning $0 ("Added disabled access-list entry with comment '--- collected above ---'.") false;
|
|
}
|
|
:local PlaceBefore ([ / %PATH% access-list find where comment="--- collected above ---" disabled ]->0);
|
|
|
|
:foreach RegTbl in=[ / %PATH% registration-table find ] do={
|
|
:local Mac [ / %PATH% registration-table get $RegTbl mac-address ];
|
|
:local AccessList ([ / %PATH% access-list find where mac-address=$Mac ]->0);
|
|
:if ([ :len $AccessList ] = 0) do={
|
|
:local Address "no dhcp lease";
|
|
:local DnsName "no dhcp lease";
|
|
:local HostName "no dhcp lease";
|
|
:local Lease ([ / ip dhcp-server lease find where mac-address=$Mac dynamic=yes status=bound ]->0);
|
|
:if ([ :len $Lease ] > 0) do={
|
|
:set Address [ / ip dhcp-server lease get $Lease address ];
|
|
:set HostName [ / ip dhcp-server lease get $Lease host-name ];
|
|
:if ([ :len $HostName ] = 0) do={
|
|
:set HostName "no hostname";
|
|
}
|
|
:set DnsName [ / ip dns static get ([ find where address=$Address ]->0) name ];
|
|
:if ([ :len $DnsName ] = 0) do={
|
|
:set DnsName "no dns name";
|
|
}
|
|
}
|
|
:local RegEntry [ / %PATH% registration-table find where mac-address=$Mac ];
|
|
:local Interface [ / %PATH% registration-table get $RegEntry interface ];
|
|
:local Ssid [ / caps-man registration-table get $RegEntry ssid ];
|
|
:local Ssid [ / interface wireless get [ find where name=$Interface ] ssid ];
|
|
:local DateTime ([ / system clock get date ] . " " . [ / system clock get time ]);
|
|
:local Vendor [ $GetMacVendor $Mac ];
|
|
:local Message ("unknown MAC address " . $Mac . " (" . $Vendor . ", " . $HostName . ") " . \
|
|
"first seen on " . $DateTime . " connected to SSID " . $Ssid . ", interface " . $Interface);
|
|
$LogPrintExit2 info $0 $Message false;
|
|
/ %PATH% access-list add place-before=$PlaceBefore comment=$Message mac-address=$Mac disabled=yes;
|
|
$SendNotification2 ({ origin=$0; \
|
|
subject=([ $SymbolForNotification "mobile-phone" ] . $Mac . " connected to " . $Ssid); \
|
|
message=("A device with unknown MAC address connected to " . $Ssid . " on " . $Identity . ".\n\n" . \
|
|
"Controller: " . $Identity . "\n" . \
|
|
"Interface: " . $Interface . "\n" . \
|
|
"SSID: " . $Ssid . "\n" . \
|
|
"MAC: " . $Mac . "\n" . \
|
|
"Vendor: " . $Vendor . "\n" . \
|
|
"Hostname: " . $HostName . "\n" . \
|
|
"Address: " . $Address . "\n" . \
|
|
"DNS name: " . $DnsName . "\n" . \
|
|
"Date: " . $DateTime) });
|
|
} else={
|
|
$LogPrintExit2 debug $0 ("MAC address " . $Mac . " already known: " . \
|
|
[ / %PATH% access-list get $AccessList comment ]) false;
|
|
}
|
|
}
|