mirror of
https://github.com/eworm-de/routeros-scripts
synced 2024-05-14 08:04:19 +00:00
71ad56aacc
Copyright (C) 2013-2020 Christian Hesse <mail@eworm.de> This program is free software: you can redistribute it and/or modify it under the terms of the GNU General Public License as published by the Free Software Foundation, either version 3 of the License, or (at your option) any later version. This program is distributed in the hope that it will be useful, but WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public License for more details. https://www.gnu.org/licenses/#GPL https://www.gnu.org/licenses/gpl.html https://www.gnu.org/licenses/gpl.md
50 lines
1.7 KiB
Plaintext
50 lines
1.7 KiB
Plaintext
#!rsc
|
|
# RouterOS script: capsman-download-packages
|
|
# Copyright (c) 2018-2020 Christian Hesse <mail@eworm.de>
|
|
# Michael Gisbers <michael@gisbers.de>
|
|
# https://git.eworm.de/cgit/routeros-scripts/about/COPYING.md
|
|
#
|
|
# download and cleanup packages for CAP installation from CAPsMAN
|
|
# https://git.eworm.de/cgit/routeros-scripts/about/doc/capsman-download-packages.md
|
|
|
|
:global CleanFilePath;
|
|
:global DownloadPackage;
|
|
:global LogPrintExit;
|
|
:global MkDir;
|
|
:global ScriptLock;
|
|
|
|
$ScriptLock "capsman-download-packages";
|
|
|
|
:local PackagePath [ $CleanFilePath [ / caps-man manager get package-path ] ];
|
|
:local InstalledVersion [ / system package update get installed-version ];
|
|
:local Updated false;
|
|
|
|
:if ([ / file print count-only where name=$PackagePath type="directory" ] = 0) do={
|
|
$MkDir $PackagePath;
|
|
$LogPrintExit info ("Created directory at package path (" . $PackagePath . \
|
|
"). Please place your packages!") false;
|
|
}
|
|
|
|
:foreach Package in=[ / file find where type=package \
|
|
package-version!=$InstalledVersion name~("^" . $PackagePath) ] do={
|
|
:local File [ / file get $Package ];
|
|
:if ($File->"package-architecture" = "mips") do={
|
|
:set ($File->"package-architecture") "mipsbe";
|
|
}
|
|
:if ($File->"package-name" = "wireless@") do={
|
|
:set ($File->"package-name") "wireless";
|
|
}
|
|
:if ([ $DownloadPackage ($File->"package-name") $InstalledVersion ($File->"package-architecture") $PackagePath ] = true) do={
|
|
:set Updated true;
|
|
/ file remove $Package;
|
|
}
|
|
}
|
|
|
|
:if ($Updated = true) do={
|
|
:if ([ / system script print count-only where name="capsman-rolling-upgrade" ] > 0) do={
|
|
/ system script run capsman-rolling-upgrade;
|
|
} else={
|
|
/ caps-man remote-cap upgrade [ find where version!=$InstalledVersion ];
|
|
}
|
|
}
|