mirror of
https://github.com/eworm-de/routeros-scripts
synced 2024-05-14 08:04:19 +00:00
71ad56aacc
Copyright (C) 2013-2020 Christian Hesse <mail@eworm.de> This program is free software: you can redistribute it and/or modify it under the terms of the GNU General Public License as published by the Free Software Foundation, either version 3 of the License, or (at your option) any later version. This program is distributed in the hope that it will be useful, but WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public License for more details. https://www.gnu.org/licenses/#GPL https://www.gnu.org/licenses/gpl.html https://www.gnu.org/licenses/gpl.md
56 lines
1.6 KiB
Plaintext
56 lines
1.6 KiB
Plaintext
#!rsc
|
|
# RouterOS script: email-backup
|
|
# Copyright (c) 2013-2020 Christian Hesse <mail@eworm.de>
|
|
# https://git.eworm.de/cgit/routeros-scripts/about/COPYING.md
|
|
#
|
|
# create and email backup and config file
|
|
# https://git.eworm.de/cgit/routeros-scripts/about/doc/email-backup.md
|
|
|
|
:global BackupPassword;
|
|
:global BackupSendBinary;
|
|
:global BackupSendExport;
|
|
:global Domain;
|
|
:global EmailBackupCc;
|
|
:global EmailBackupTo;
|
|
:global Identity;
|
|
|
|
:global CharacterReplace;
|
|
:global DeviceInfo;
|
|
:global LogPrintExit;
|
|
|
|
:if ($BackupSendBinary != true && \
|
|
$BackupSendExport != true) do={
|
|
$LogPrintExit error ("Configured to send neither backup nor config export.") true;
|
|
}
|
|
|
|
# filename based on identity
|
|
:local FileName [ $CharacterReplace ($Identity . "." . $Domain) "." "_" ];
|
|
:local BackupFile "none";
|
|
:local ConfigFile "none";
|
|
:local Attach [ :toarray "" ];
|
|
|
|
# binary backup
|
|
:if ($BackupSendBinary = true) do={
|
|
/ system backup save encryption=aes-sha256 name=$FileName password=$BackupPassword;
|
|
:set BackupFile ($FileName . ".backup");
|
|
:set Attach ($Attach, $BackupFile);
|
|
}
|
|
|
|
# create configuration export
|
|
:if ($BackupSendExport = true) do={
|
|
/ export terse file=$FileName;
|
|
:set ConfigFile ($FileName . ".rsc");
|
|
:set Attach ($Attach, $ConfigFile);
|
|
}
|
|
|
|
# send email with status and files
|
|
/ tool e-mail send to=$EmailBackupTo cc=$EmailBackupCc \
|
|
subject=("[" . $Identity . "] Backup & Config") \
|
|
body=("See attached files for backup and config export for " . \
|
|
$Identity . ".\n\n" . \
|
|
[ $DeviceInfo ] . "\n\n" . \
|
|
"Backup file: " . $BackupFile . "\n" . \
|
|
"Config file: " . $ConfigFile) \
|
|
file=$Attach;
|
|
}
|