mirror of
https://github.com/eworm-de/routeros-scripts
synced 2024-05-14 08:04:19 +00:00
870f00bb36
___ _ ___ __
/ _ )(_)__ _ / _/__ _/ /_
/ _ / / _ `/ / _/ _ `/ __/
/____/_/\_, / /_/ \_,_/\__/
_ __ /___/ _ __
| | / /___ __________ (_)___ ____ _/ /
| | /| / / __ `/ ___/ __ \/ / __ \/ __ `/ /
| |/ |/ / /_/ / / / / / / / / / / /_/ /_/
|__/|__/\__,_/_/ /_/ /_/_/_/ /_/\__, (_)
/____/
RouterOS has some odd behavior when it comes to variable names. Let's
have a look at the interfaces:
[admin@MikroTik] > / interface print where name=en1
Flags: D - dynamic, X - disabled, R - running, S - slave
# NAME TYPE ACTUAL-MTU L2MTU
0 RS en1 ether 1500 1598
That looks ok. Now we use a script:
{ :local interface "en1";
/ interface print where name=$interface; }
And the result...
[admin@MikroTik] > { :local interface "en1";
{... / interface print where name=$interface; }
Flags: D - dynamic, X - disabled, R - running, S - slave
# NAME TYPE ACTUAL-MTU L2MTU
0 RS en1 ether 1500 1598
... still looks ok.
We make a little modification to the script:
{ :local name "en1";
/ interface print where name=$name; }
And the result:
[admin@MikroTik] > { :local name "en1";
{... / interface print where name=$name; }
Flags: D - dynamic, X - disabled, R - running, S - slave
# NAME TYPE ACTUAL-MTU L2MTU
0 RS en1 ether 1500 1598
1 S en2 ether 1500 1598
2 S en3 ether 1500 1598
3 S en4 ether 1500 1598
4 S en5 ether 1500 1598
5 R br-local bridge 1500 1598
Ups! The filter has no effect!
That happens whenever the variable name ($name) matches the property
name (name=).
And another modification:
{ :local type "en1";
/ interface print where name=$type; }
And the result:
[admin@MikroTik] > { :local type "en1";
{... / interface print where name=$type; }
Flags: D - dynamic, X - disabled, R - running, S - slave
# NAME TYPE ACTUAL-MTU L2MTU
Ups! Nothing?
Even if the variable name ($type) matches whatever property name (type=)
things go wrong.
The answer from MikroTik support (in Ticket#2019010222000454):
> This is how scripting works in RouterOS and we will not fix it.
To get around this we use variable names in CamelCase. Let's hope
Mikrotik never ever introduces property names in CamelCase...
*fingers crossed*
60 lines
2.6 KiB
Plaintext
60 lines
2.6 KiB
Plaintext
#!rsc
|
|
# RouterOS script: collect-wireless-mac.local
|
|
# Copyright (c) 2013-2019 Christian Hesse <mail@eworm.de>
|
|
#
|
|
# collect wireless mac adresses in access list
|
|
#
|
|
# !! Do not edit this file, it is generated from template!
|
|
|
|
:global Identity;
|
|
|
|
:global GetMacVendor;
|
|
:global SendNotification;
|
|
|
|
:local PlaceBefore [ / interface wireless access-list find where comment="--- collected above ---" disabled ];
|
|
:if ([ :len $PlaceBefore ] = 0) do={
|
|
:error "Missing disabled access-list entry with comment '--- collected above ---'";
|
|
}
|
|
|
|
:foreach RegTbl in=[ / interface wireless registration-table find ] do={
|
|
:local Mac [ / interface wireless registration-table get $RegTbl mac-address ];
|
|
:local AccessList [ :pick [ / interface wireless access-list find where mac-address=$Mac ] 0 ];
|
|
:if ([ :len $AccessList ] = 0) do={
|
|
:local HostName "no dhcp lease";
|
|
:local Address "no dhcp lease";
|
|
:local Lease [ / ip dhcp-server lease find where mac-address=$Mac ];
|
|
:if ([ :len $Lease ] > 0) do={
|
|
:set HostName [ / ip dhcp-server lease get $Lease host-name ];
|
|
:set Address [ / ip dhcp-server lease get $Lease address ];
|
|
}
|
|
:if ([ :len $HostName ] = 0) do={
|
|
:set HostName "no hostname";
|
|
}
|
|
:if ([ :len $Address ] = 0) do={
|
|
:set Address "no address";
|
|
}
|
|
:local RegEntry [ / interface wireless registration-table find where mac-address=$Mac ];
|
|
:local Interface [ / interface wireless registration-table get $RegEntry interface ];
|
|
:local Ssid [ / interface wireless get [ find where name=$Interface ] ssid ];
|
|
:local DateTime ([ / system clock get date ] . " " . [ / system clock get time ]);
|
|
:local Vendor [ $GetMacVendor $Mac ];
|
|
:local Message ("unknown MAC address " . $Mac . " (" . $Vendor . ", " . $HostName . ") " . \
|
|
"first seen on " . $DateTime . " connected to SSID " . $Ssid . ", interface " . $Interface);
|
|
/ log info $Message;
|
|
/ interface wireless access-list add place-before=$PlaceBefore comment=$Message mac-address=$Mac disabled=yes;
|
|
$SendNotification ($Mac . " connected to " . $Ssid) \
|
|
("A device with unknown MAC address connected to " . $Ssid . " on " . $Identity . ".\n\n" . \
|
|
"Controller: " . $Identity . "\n" . \
|
|
"Interface: " . $Interface . "\n" . \
|
|
"SSID: " . $Ssid . "\n" . \
|
|
"MAC: " . $Mac . "\n" . \
|
|
"Vendor: " . $Vendor . "\n" . \
|
|
"Hostname: " . $HostName . "\n" . \
|
|
"Address: " . $Address . "\n" . \
|
|
"Date: " . $DateTime);
|
|
} else={
|
|
:local Comment [ / interface wireless access-list get $AccessList comment ];
|
|
:log debug ("MAC address " . $Mac . " already known: " . $Comment);
|
|
}
|
|
}
|