mirror of
https://github.com/eworm-de/routeros-scripts
synced 2024-05-14 08:04:19 +00:00
71ad56aacc
Copyright (C) 2013-2020 Christian Hesse <mail@eworm.de> This program is free software: you can redistribute it and/or modify it under the terms of the GNU General Public License as published by the Free Software Foundation, either version 3 of the License, or (at your option) any later version. This program is distributed in the hope that it will be useful, but WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public License for more details. https://www.gnu.org/licenses/#GPL https://www.gnu.org/licenses/gpl.html https://www.gnu.org/licenses/gpl.md
40 lines
1.9 KiB
Plaintext
40 lines
1.9 KiB
Plaintext
#!rsc
|
|
# RouterOS script: bridge-port-to-default
|
|
# Copyright (c) 2013-2020 Christian Hesse <mail@eworm.de>
|
|
# https://git.eworm.de/cgit/routeros-scripts/about/COPYING.md
|
|
#
|
|
# reset bridge ports to default bridge
|
|
# https://git.eworm.de/cgit/routeros-scripts/about/doc/bridge-port.md
|
|
|
|
:global BridgePortTo;
|
|
|
|
:global LogPrintExit;
|
|
:global ParseKeyValueStore;
|
|
|
|
:foreach BridgePort in=[ / interface bridge port find where comment~"." ] do={
|
|
:local BridgePortVal [ / interface bridge port get $BridgePort ];
|
|
:foreach Config,BridgeDefault in=[ $ParseKeyValueStore ($BridgePortVal->"comment") ] do={
|
|
:if ($Config = $BridgePortTo) do={
|
|
:if ($BridgeDefault = "dhcp-client") do={
|
|
:if ($BridgePortVal->"disabled" = false) do={
|
|
$LogPrintExit info ("Disabling bridge port for interface " . $BridgePortVal->"interface" . ", enabling dhcp client.") false;
|
|
/ interface bridge port disable $BridgePort;
|
|
/ ip dhcp-client enable [ find where interface=$BridgePortVal->"interface" comment="toggle with bridge port" disabled=yes ];
|
|
}
|
|
} else={
|
|
:if ($BridgePortVal->"disabled" = true) do={
|
|
$LogPrintExit info ("Enabling bridge port for interface " . $BridgePortVal->"interface" . ", disabling dhcp client.") false;
|
|
/ ip dhcp-client disable [ find where interface=$BridgePortVal->"interface" comment="toggle with bridge port" disabled=no ];
|
|
/ interface bridge port enable $BridgePort;
|
|
}
|
|
:if ($BridgeDefault != $BridgePortVal->"bridge") do={
|
|
$LogPrintExit info ("Changing interface " . $BridgePortVal->"interface" . " to " . $BridgePortTo . " bridge " . $BridgeDefault) false;
|
|
/ interface bridge port set bridge=$BridgeDefault $BridgePort;
|
|
} else={
|
|
$LogPrintExit debug ("Interface " . $BridgePortVal->"interface" . " already connected to " . $BridgePortTo . " bridge " . $BridgeDefault) false;
|
|
}
|
|
}
|
|
}
|
|
}
|
|
}
|