mirror of
https://github.com/eworm-de/routeros-scripts
synced 2024-05-14 08:04:19 +00:00
ceaa83b83e
... and fix logging. Logging with severity from variable (:log $severity ...) is not possible, this is considered a syntax error. Also the 'workaround' with parsing code failed with missing message in log. The reliable code is a lot longer, so merge the two functions to save a lot of duplicate code.
57 lines
1.8 KiB
Plaintext
57 lines
1.8 KiB
Plaintext
#!rsc
|
|
# RouterOS script: packages-update
|
|
# Copyright (c) 2019-2020 Christian Hesse <mail@eworm.de>
|
|
#
|
|
# download packages and reboot for installation
|
|
|
|
:global DownloadPackage;
|
|
:global ScriptFromTerminal;
|
|
:global ScriptLock;
|
|
:global LogPrintExit;
|
|
|
|
$ScriptLock "packages-update";
|
|
|
|
:local Update [ / system package update get ];
|
|
|
|
:if ([ :typeof ($Update->"latest-version") ] = "nothing") do={
|
|
$LogPrintExit warning "Latest version is not known." true;
|
|
}
|
|
|
|
:if ($Update->"installed-version" = $Update->"latest-version") do={
|
|
$LogPrintExit info ("Version " . $Update->"latest-version" . " is already installed.") true;
|
|
}
|
|
|
|
:foreach Package in=[ / system package find where !bundle ] do={
|
|
:local PkgName [ / system package get $Package name ];
|
|
if ([ $DownloadPackage $PkgName ($Update->"latest-version") ] = false) do={
|
|
$LogPrintExit error ("Download for package " . $PkgName . " failed.") true;
|
|
}
|
|
}
|
|
|
|
:foreach Script in=[ / system script find where name~"^(email|upload)-backup\$" ] do={
|
|
/ system script run $Script;
|
|
}
|
|
|
|
:if ([ $ScriptFromTerminal "packages-update" ] = true) do={
|
|
:if (!([ /system resource get version ] ~ ($Update->"channel"))) do={
|
|
:put "Update channel changed. Want to downgrade? [y/N]";
|
|
:if ([ :terminal inkey timeout=60 ] = 121) do={
|
|
:log info ("Rebooting for downgrade.");
|
|
:delay 1s;
|
|
/ system package downgrade;
|
|
}
|
|
}
|
|
|
|
:put "Do you want to (s)chedule reboot or (r)eboot now? [s/R]";
|
|
:if ([ :terminal inkey timeout=60 ] = 115) do={
|
|
/ system scheduler add name="reboot-for-update" start-time=03:00:00 interval=1d \
|
|
on-event=(":global RandomDelay; \$RandomDelay 3600; " . \
|
|
"/ system scheduler remove reboot-for-update; / system reboot;");
|
|
$LogPrintExit info ("Scheduled reboot for update between 03:00 and 04:00.") true;
|
|
}
|
|
}
|
|
|
|
:log info ("Rebooting for update.");
|
|
:delay 1s;
|
|
/ system reboot;
|