Crash_Override/routeros-scripts
1
0
Fork 0
mirror of https://github.com/eworm-de/routeros-scripts synced 2024-05-14 08:04:19 +00:00
Code Issues Projects Releases Packages Wiki Activity

add script 'unattended-lte-firmware-upgrade'

Browse source
This commit is contained in:
Christian Hesse 2019-01-02 22:27:31 +01:00
parent 29a363649d
commit e2b5124e8c
1 changed files with 29 additions and 0 deletions
Show stats Download patch file Download diff file Expand all files Collapse all files

29
unattended-lte-firmware-upgrade Normal file
View file

@ -0,0 +1,29 @@
#!rsc
# RouterOS script: unattended-lte-firmware-upgrade
# Copyright (c) 2018-2019 Christian Hesse <mail@eworm.de>
#
# schedule unattended lte firmware upgrade
:foreach interface in=[ / interface lte find ] do={
:local firmware;
:local intname [ / interface lte get $interface name ];
do {
:set firmware [ / interface lte firmware-upgrade $interface once as-value ];
# strip the extra line break (TODO: remove when fixed upstream)
:set ($firmware->"latest") [ :pick ($firmware->"latest") 0 [ :find ($firmware->"latest") "\n" ] ];
} on-error={
:log debug ("Could not get latest LTE firmware version for interface " . $intname . ".");
}
:if (($firmware->"installed") != ($firmware->"latest")) do={
:log info ("Scheduling LTE firmware upgrade for interface " . $intname . ".");
/ system script add name=($intname . "-firmware-upgrade") source=("# unattended-lte-firmware-upgrade\n" . \
"/ system scheduler remove " . $intname . "-firmware-upgrade;\n" . \
"/ system script remove " . $intname . "-firmware-upgrade;\n" . \
"/ interface lte firmware-upgrade " . $intname . " upgrade=yes;\n" . \
":log info (\"LTE firmware upgrade finished, waiting for installation before reset.\");\n" . \
":delay 150s;\n" . \
"/ interface lte at-chat " . $intname . " input=\"AT+RESET\";");
/ system scheduler add name=($intname . "-firmware-upgrade") on-event=($intname . "-firmware-upgrade") interval=1m;
}
}