routeros-scripts/cloud-backup

#!rsc
# RouterOS script: cloud-backup
# Copyright (c) 2013-2020 Christian Hesse <mail@eworm.de>
#
# upload backup to MikroTik cloud
# https://git.eworm.de/cgit/routeros-scripts/about/doc/cloud-backup.md

:global BackupPassword;
:global Identity;

:global DeviceInfo;
:global SendNotification;

:do {
  # we are not interested in output, but print without count-only is
  # required to fetch information from cloud
  / system backup cloud print as-value;
  :if ([ / system backup cloud print count-only ] > 0) do={
    / system backup cloud upload-file action=create-and-upload \
        password=$BackupPassword replace=[ get ([ find ]->0) name ];
  } else={
    / system backup cloud upload-file action=create-and-upload \
        password=$BackupPassword;
  }
  :local Cloud [ / system backup cloud get ([ find ]->0) ];

  $SendNotification "Cloud backup" \
    ("Uploaded backup for " . $Identity . " to cloud.\n\n" . \
      [ $DeviceInfo ] . "\n\n" . \
      "Name:           " . $Cloud->"name" . "\n" . \
      "Size:           " . $Cloud->"size" . "\n" . \
      "Download key:   " . $Cloud->"secret-download-key") "" "true";
} on-error={
  :log error ("Failed uploading backup for " . $Identity . " to cloud.");
}