routeros-scripts/email-backup

#!rsc by RouterOS
# RouterOS script: email-backup
# Copyright (c) 2013-2021 Christian Hesse <mail@eworm.de>
# https://git.eworm.de/cgit/routeros-scripts/about/COPYING.md
#
# create and email backup and config file
# https://git.eworm.de/cgit/routeros-scripts/about/doc/email-backup.md

:local 0 "email-backup";
:global GlobalFunctionsReady;
:while ($GlobalFunctionsReady != true) do={ :delay 500ms; }

:global BackupPassword;
:global BackupRandomDelay;
:global BackupSendBinary;
:global BackupSendExport;
:global Domain;
:global EmailBackupCc;
:global EmailBackupTo;
:global Identity;

:global CharacterReplace;
:global DeviceInfo;
:global LogPrintExit2;
:global RandomDelay;
:global ScriptFromTerminal;
:global WaitForFile;
:global WaitFullyConnected;

:if ($BackupSendBinary != true && \
     $BackupSendExport != true) do={
  $LogPrintExit2 error $0 ("Configured to send neither backup nor config export.") true;
}

:if ([ :len $EmailBackupTo ] = 0) do={
  $LogPrintExit2 error $0 ("Configuration is missing recipient for e-mail backup.") true;
}

$WaitFullyConnected;

:if ([ $ScriptFromTerminal $0 ] = false && $BackupRandomDelay > 0) do={
  $RandomDelay $BackupRandomDelay;
}

# filename based on identity
:local FileName [ $CharacterReplace ($Identity . "." . $Domain) "." "_" ];
:local BackupFile "none";
:local ConfigFile "none";
:local Attach [ :toarray "" ];

# binary backup
:if ($BackupSendBinary = true) do={
  / system backup save encryption=aes-sha256 name=$FileName password=$BackupPassword;
  $WaitForFile ($FileName . ".backup");
  :set BackupFile ($FileName . ".backup");
  :set Attach ($Attach, $BackupFile);
}

# create configuration export
:if ($BackupSendExport = true) do={
  / export terse file=$FileName;
  $WaitForFile ($FileName . ".rsc");
  :set ConfigFile ($FileName . ".rsc");
  :set Attach ($Attach, $ConfigFile);
}

# send email with status and files
/ tool e-mail send to=$EmailBackupTo cc=$EmailBackupCc \
    subject=("[" . $Identity . "] Backup & Config") \
    body=("See attached files for backup and config export for " . \
      $Identity . ".\n\n" . \
      [ $DeviceInfo ] . "\n\n" . \
      "Backup file:    " . $BackupFile . "\n" . \
      "Config file:    " . $ConfigFile) \
    file=$Attach;